Initial import of libqt-perl (not yet TQt compatible)

3 files changed, 141 insertions, 0 deletions

diff --git a/PerlQt/tutorials/t9/CannonField.pm b/PerlQt/tutorials/t9/CannonField.pm
new file mode 100644
index 0000000..e12489a
--- /dev/null
+++ b/PerlQt/tutorials/t9/CannonField.pm
@@ -0,0 +1,48 @@
+package CannonField;
+use strict;
+use Qt;
+use Qt::isa qw(Qt::Widget);
+use Qt::signals
+	angleChanged => ['int'];
+use Qt::slots
+	setAngle => ['int'];
+use Qt::attributes qw(
+	ang
+);
+use POSIX qw(atan);
+
+sub angle () { ang }
+
+sub NEW {
+    shift->SUPER::NEW(@_);
+
+    ang = 45;
+    setPalette(Qt::Palette(Qt::Color(250, 250, 200)));
+}
+
+sub setAngle {
+    my $degrees = shift;
+    $degrees = 5 if $degrees < 5;
+    $degrees = 70 if $degrees > 70;
+    return if ang == $degrees;
+    ang = $degrees;
+    repaint();
+    emit angleChanged(ang);
+}
+
+sub paintEvent {
+    my $p = Qt::Painter(this);
+    $p->setBrush(&blue);
+    $p->setPen(&NoPen);
+
+    $p->translate(0, rect()->bottom);
+    $p->drawPie(Qt::Rect(-35, -35, 70, 70), 0, 90*16);
+    $p->rotate(- ang);
+    $p->drawRect(Qt::Rect(33, -4, 15, 8));
+}
+
+sub sizePolicy {
+    Qt::SizePolicy(&Qt::SizePolicy::Expanding, &Qt::SizePolicy::Expanding);
+}
+
+1;
diff --git a/PerlQt/tutorials/t9/LCDRange.pm b/PerlQt/tutorials/t9/LCDRange.pm
new file mode 100644
index 0000000..be0f8ec
--- /dev/null
+++ b/PerlQt/tutorials/t9/LCDRange.pm
@@ -0,0 +1,43 @@
+package LCDRange;
+use strict;
+use Qt;
+use Qt::isa qw(Qt::VBox);
+use Qt::slots 
+	setValue => ['int'],
+	setRange => ['int', 'int'];
+use Qt::signals
+	valueChanged => ['int'];
+use Qt::attributes qw(
+	slider
+);
+
+sub NEW {
+    shift->SUPER::NEW(@_);
+
+    my $lcd = Qt::LCDNumber(2, this, "lcd");
+
+    slider = Qt::Slider(&Horizontal, this, "slider");
+    slider->setRange(0, 99);
+    slider->setValue(0);
+    $lcd->connect(slider, SIGNAL('valueChanged(int)'), SLOT('display(int)'));
+    this->connect(slider, SIGNAL('valueChanged(int)'), SIGNAL('valueChanged(int)'));
+
+    setFocusProxy(slider);
+}
+
+sub value { slider->value }
+
+sub setValue { slider->setValue(shift) }
+
+sub setRange {
+    my($minVal, $maxVal) = @_;
+    if($minVal < 0 || $maxVal > 99 || $minVal > $maxVal) {
+	warn "LCDRange::setRange($minVal,$maxVal)\n" .
+	     "\tRange must be 0..99\n" .
+	     "\tand minVal must not be greater than maxVal\n";
+	return;
+    }
+    slider->setRange($minVal, $maxVal);
+}
+
+1;
diff --git a/PerlQt/tutorials/t9/t9.pl b/PerlQt/tutorials/t9/t9.pl
new file mode 100644
index 0000000..192041c
--- /dev/null
+++ b/PerlQt/tutorials/t9/t9.pl
@@ -0,0 +1,50 @@
+#!/usr/bin/perl -w
+use strict;
+use blib;
+
+package MyWidget;
+use strict;
+use Qt;
+use Qt::isa qw(Qt::Widget);
+
+use LCDRange;
+use CannonField;
+
+sub NEW {
+    shift->SUPER::NEW(@_);
+
+    my $quit = Qt::PushButton("&Quit", this, "quit");
+    $quit->setFont(Qt::Font("Times", 18, &Qt::Font::Bold));
+
+    Qt::app->connect($quit, SIGNAL('clicked()'), SLOT('quit()'));
+
+    my $angle = LCDRange(this, "angle");
+    $angle->setRange(5, 70);
+
+    my $cannonField = CannonField(this, "cannonField");
+
+    $cannonField->connect($angle, SIGNAL('valueChanged(int)'), SLOT('setAngle(int)'));
+    $angle->connect($cannonField, SIGNAL('angleChanged(int)'), SLOT('setValue(int)'));
+
+    my $grid = Qt::GridLayout(this, 2, 2, 10);
+    $grid->addWidget($quit, 0, 0);
+    $grid->addWidget($angle, 1, 0, &AlignTop);
+    $grid->addWidget($cannonField, 1, 1);
+    $grid->setColStretch(1, 10);
+
+    $angle->setValue(60);
+    $angle->setFocus();
+}
+
+package main;
+use Qt;
+use MyWidget;
+
+Qt::Application::setColorSpec(&Qt::Application::CustomColor);
+my $a = Qt::Application(\@ARGV);
+
+my $w = MyWidget;
+$w->setGeometry(100, 100, 500, 355);
+$a->setMainWidget($w);
+$w->show;
+exit $a->exec;