conversion to the cmake building system

Signed-off-by: gregory guy <[email protected]>

7 files changed, 176 insertions, 2 deletions

diff --git a/CMakeLists.txt b/CMakeLists.txt
new file mode 100644
index 0000000..91d6c5d
--- /dev/null
+++ b/CMakeLists.txt
@@ -0,0 +1,70 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8 )
+
+
+#### general package setup
+
+project( smartcardauth )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckSymbolExists      )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( src )
+add_subdirectory( usr/bin )
+add_subdirectory( usr/share/initramfs-tools/hooks )
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )
diff --git a/ConfigureChecks.cmake b/ConfigureChecks.cmake
new file mode 100644
index 0000000..d2ac512
--- /dev/null
+++ b/ConfigureChecks.cmake
@@ -0,0 +1,66 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+# required stuff
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+tde_setup_largefiles( )
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  tde_setup_gcc_visibility( )
+endif( WITH_GCC_VISIBILITY )
+
+
+##### check for gnutls
+
+pkg_search_module( GNUTLS gnutls )
+if( NOT GNUTLS_FOUND )
+  tde_message_fatal( "GNUTLS is required but was not found on your system" )
+endif( NOT GNUTLS_FOUND )
+
+
+##### check for OpenSSL
+
+pkg_search_module( SSL openssl )
+if( NOT SSL_FOUND )
+   check_include_file( openssl/ssl.h HAVE_OPENSSL_H )
+   check_library_exists( ssl OPENSSL_init_ssl "" HAVE_LIBSSL_11 )
+   if( NOT HAVE_LIBSSL_11 )
+      check_library_exists( ssl SSL_library_init "" HAVE_LIBSSL )
+   endif( )
+   check_library_exists( crypto EVP_EncryptInit_ex "" HAVE_LIBCRYPTO )
+   if( HAVE_OPENSSL_H AND (HAVE_LIBSSL_11 OR HAVEL_LIBSSL) AND HAVE_LIBCRYPTO )
+      set( SSL_FOUND 1 CACHE INTERNAL "" FORCE )
+      find_file( OPENSSLV_H openssl/opensslv.h )
+      file( STRINGS "${OPENSSLV_H}" SSL_VERSION REGEX "#[ \t]*define[ \t]*OPENSSL_VERSION_TEXT" )
+      string( REGEX REPLACE "# *define[ \t]*OPENSSL_VERSION_TEXT[ \t]*\"[^0-9 ]* *([^ ]*).*" "\\1"
+              SSL_VERSION "${SSL_VERSION}" )
+      set( SSL_VERSION "${SSL_VERSION}" CACHE INTERNAL "" FORCE )
+      message( STATUS "Found OpenSSL: version ${SSL_VERSION}" )
+   endif( HAVE_OPENSSL_H AND (HAVE_LIBSSL_11 OR HAVEL_LIBSSL) AND HAVE_LIBCRYPTO )
+endif( NOT SSL_FOUND )
+if( NOT SSL_FOUND )
+  tde_message_fatal( "SSL support is required but was not found on your system" )
+endif( NOT SSL_FOUND )
+
+
+##### check for pkcs11-helper
+
+pkg_search_module( LIBPKCS11-HELPER libpkcs11-helper-1 )
+if( NOT LIBPKCS11-HELPER_FOUND )
+  tde_message_fatal( "libpkcs11-helper-1 is required but was not found on your system" )
+endif( NOT LIBPKCS11-HELPER_FOUND )
+
+
diff --git a/config.h.cmake b/config.h.cmake
new file mode 100644
index 0000000..61ede3a
--- /dev/null
+++ b/config.h.cmake
@@ -0,0 +1,8 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
new file mode 100644
index 0000000..9253d56
--- /dev/null
+++ b/src/CMakeLists.txt
@@ -0,0 +1,20 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+)
+
+
+##### cardpincheck (executable)
+
+tde_add_executable( cardpincheck
+
+  SOURCES
+        cardpincheck.c
+  LINK
+     ${SSL_LIBRARIES}
+     ${GNUTLS_LIBRARIES}
+     ${LIBPKCS11-HELPER_LIBRARIES}
+     
+  DESTINATION ${BIN_INSTALL_DIR}
+)
diff --git a/src/Makefile b/src/Makefile
index f0dac07..70d8383 100644
--- a/src/Makefile
+++ b/src/Makefile
@@ -1,10 +1,12 @@
+LDFLAGS=-ldl -lpthread -lgnutls -lcrypto -lpkcs11-helper
+
 all: cardpincheck.o cardpincheck
 
 cardpincheck.o: cardpincheck.c
-	gcc cardpincheck.c -c
+	$(CC) cardpincheck.c -c
 
 cardpincheck: cardpincheck.o
-	gcc cardpincheck.o -o cardpincheck -ldl -lpthread -lgnutls -lcrypto -lpkcs11-helper
+	$(CC) cardpincheck.o -o cardpincheck $(LDFLAGS)
 
 clean: 
 	rm -f cardpincheck.o cardpincheck
diff --git a/usr/bin/CMakeLists.txt b/usr/bin/CMakeLists.txt
new file mode 100644
index 0000000..db64318
--- /dev/null
+++ b/usr/bin/CMakeLists.txt
@@ -0,0 +1,4 @@
+install(
+    PROGRAMS cryptosmartcard.sh
+    DESTINATION ${BIN_INSTALL_DIR}
+)
diff --git a/usr/share/initramfs-tools/hooks/CMakeLists.txt b/usr/share/initramfs-tools/hooks/CMakeLists.txt
new file mode 100644
index 0000000..5e05159
--- /dev/null
+++ b/usr/share/initramfs-tools/hooks/CMakeLists.txt
@@ -0,0 +1,4 @@
+install(
+    PROGRAMS cryptlukssc
+    DESTINATION ${SHARE_INSTALL_PREFIX}/initramfs-tools/hooks
+)