Add jasper (JPEG 2000) ebuild.

Gentoo removed it from the Portage, so
we add it to the overlay to keep support.

Thanks to agris from IRC for the report.

Signed-off-by: Chris <[email protected]>

1 files changed, 65 insertions, 0 deletions

diff --git a/media-libs/jasper/jasper-2.0.16.ebuild b/media-libs/jasper/jasper-2.0.16.ebuild
new file mode 100644
index 00000000..e38d99a4
--- /dev/null
+++ b/media-libs/jasper/jasper-2.0.16.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-multilib
+
+DESCRIPTION="Implementation of the codec specified in the JPEG-2000 Part-1 standard"
+HOMEPAGE="https://www.ece.uvic.ca/~mdadams/jasper/"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mdadams/jasper.git"
+else
+	SRC_URI="https://github.com/mdadams/${PN}/archive/version-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+	S="${WORKDIR}/${PN}-version-${PV}"
+fi
+
+# We limit memory usage to 128 MiB by default, specified in bytes
+: ${JASPER_MEM_LIMIT:=134217728}
+
+LICENSE="JasPer2.0"
+SLOT="0/4"
+IUSE="doc jpeg opengl"
+
+RDEPEND="
+	jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
+	opengl? (
+		>=virtual/opengl-7.0-r1:0[${MULTILIB_USEDEP}]
+		>=media-libs/freeglut-2.8.1:0[${MULTILIB_USEDEP}]
+		virtual/glu[${MULTILIB_USEDEP}]
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+		x11-libs/libXmu[${MULTILIB_USEDEP}]
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DALLOW_IN_SOURCE_BUILD=OFF
+		-DBASH_PROGRAM="${EPREFIX}"/bin/bash
+		-DJAS_ENABLE_ASAN=OFF
+		-DJAS_ENABLE_LSAN=OFF
+		-DJAS_ENABLE_MSAN=OFF
+		-DJAS_ENABLE_SHARED=ON
+		-DJAS_ENABLE_STRICT=ON
+		-DJAS_ENABLE_USAN=OFF
+		-DCMAKE_INSTALL_DOCDIR=share/doc/${PF}
+
+		# JPEG
+		-DJAS_ENABLE_LIBJPEG=$(usex jpeg)
+		-DCMAKE_DISABLE_FIND_PACKAGE_JPEG=$(usex !jpeg)
+
+		# OpenGL
+		-DJAS_ENABLE_OPENGL=$(usex opengl)
+		-DCMAKE_DISABLE_FIND_PACKAGE_OpenGL=$(usex !opengl)
+
+		# Doxygen
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=$(multilib_native_usex doc OFF ON)
+	)
+	cmake-utils_src_configure
+}