# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contribuitor: David C. Rankin <drankinatty at gmail dot com>

_mod=libcaldav
_cat=dependencies/
_kdemod="${_mod/tde/kde}"

pkgname="tde-${_mod}"
pkgver=14.0.13
pkgrel=1
pkgdesc="A client library adding support for the CalDAV protocol (rfc4791)"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
url="https://scm.trinitydesktop.org/scm/git/${_mod}"
license=('GPL')
groups=('tde-libs')
depends=('curl' 'glib2')
makedepends=('doxygen' 'tde-cmake-trinity')
optdepends=()
provides=("${_mod}")
replaces=("trinity-${_mod}")
options=('staticlibs' 'libtool' '!strip')
install=
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/${_cat}${_mod}-trinity-${pkgver}.tar.xz")
md5sums=('4d543a91fedd1b38159d9680989d5794')

_prefix=/usr

build() {
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p ${srcdir}/build
   cd ${srcdir}/build

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver}/ \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX=${_prefix} \
      -DWITH_GCC_VISIBILITY=ON

   msg "Building $pkgname..."
   ninja $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   DESTDIR="$pkgdir" ninja -j1 install
}