Commit initial kdeartwork CMake support, courtesy of Golubev Alexander

git-svn-id: svn://anonsvn.kde.org/home/kde/branches/trinity/kdeartwork@1259766 283d02a7-25f6-0310-bc7c-ecb5cbfe19da

6 files changed, 330 insertions, 0 deletions

diff --git a/kscreensaver/CMakeLists.txt b/kscreensaver/CMakeLists.txt
new file mode 100644
index 00000000..0c453adb
--- /dev/null
+++ b/kscreensaver/CMakeLists.txt
@@ -0,0 +1,17 @@
+#################################################
+#
+#  (C) 2011 Golubev Alexander
+#  fatzer2 (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( kdesavers )
+add_subdirectory( kpartsaver)
+if( WITH_XSCREENSAVER )
+  add_subdirectory( kxsconfig )
+  add_subdirectory( xsavers )
+endif( WITH_XSCREENSAVER )
diff --git a/kscreensaver/kdesavers/CMakeLists.txt b/kscreensaver/kdesavers/CMakeLists.txt
new file mode 100644
index 00000000..3a74df96
--- /dev/null
+++ b/kscreensaver/kdesavers/CMakeLists.txt
@@ -0,0 +1,145 @@
+#################################################
+#
+#  (C) 2011 Golubev Alexander
+#  fatzer2 (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+# ##### The "normal" screensavers ###############
+
+set( kbanner_SOURCES    banner.cpp )
+set( kbanner_DESKTOP    KBanner.desktop )
+set( kpolygon_SOURCES   polygon.cpp )
+set( kpolygon_DESKTOP   KPolygon.desktop )
+set( klines_SOURCES     lines.cpp )
+set( klines_DESKTOP     KLines-saver.desktop )
+set( klorenz_SOURCES    lorenz.cpp )
+set( klorenz_DESKTOP    KLorenz.desktop )
+set( kslideshow_SOURCES slideshow.cpp slideshowcfg.ui )
+set( kslideshow_DESKTOP KSlideshow.desktop )
+set( kblob_SOURCES      blob.cpp )
+set( kblob_DESKTOP      KBlob.desktop )
+set( kvm_SOURCES        kvm.cpp vm.c vm_random.c )
+set( kvm_DESKTOP        KVm.desktop )
+
+set( kslideshow_LINK	kio-shared )
+
+set( NORMAL_SCREENSAVERS 
+	kbanner kpolygon kslideshow	klines klorenz kblob kvm )
+
+##### X11 screensavers ##########################
+
+set( kscience_SOURCES   science.cpp )	
+set( kscience_DESKTOP   KScience.desktop )
+
+set( X11_SCREENSAVERS kscience)
+
+##### The GL screensavers #######################
+
+set( kfountain_SOURCES  fountain.cpp fountaincfg.ui )
+set( kfountain_DESKTOP  KFountain.desktop )
+set( kwave_SOURCES      wave.cpp wavecfg.ui )
+set( kwave_DESKTOP      KWave.desktop )
+set( kgravity_SOURCES   gravity.cpp gravitycfg.ui )
+set( kgravity_DESKTOP   KGravity.desktop )
+set( kflux_SOURCES      Flux.cpp )
+set( kflux_DESKTOP      KFlux.desktop )
+set( keuphoria_SOURCES  Euphoria.cpp )
+set( keuphoria_DESKTOP  KEuphoria.desktop )
+set( ksolarwinds_SOURCES SolarWinds.cpp )
+set( ksolarwinds_DESKTOP KSolarWinds.desktop )
+set( krotation_SOURCES  rotation.cpp rotationcfg.ui sspreviewarea.cpp
+   	rkodesolver.cpp vec3.cpp )
+set( krotation_DESKTOP  KRotation.desktop )
+set( kpendulum_SOURCES  pendulum.cpp pendulumcfg.ui sspreviewarea.cpp
+   	rkodesolver.cpp )
+set( kpendulum_DESKTOP  KPendulum.desktop )
+set( OPENGL_SCREENSAVERS kfountain kwave kgravity kflux keuphoria ksolarwinds
+	krotation kpendulum )
+
+##### The GL-Arts screensavers ##################
+
+set( kfiresaver_SOURCES firesaversetup.ui firesaverparticle.cpp
+   	firesaverwriter.cpp	firesaver.cpp )
+set( kfiresaver_DESKTOP KFiresaver.desktop )
+set( kfiresaver_LINK artskde-shared )
+set( GL_ARTS_SCREENSAVERS kfiresaver )
+
+##### The LIBART screensavers ###################
+
+set( kclock_SOURCES	kclock.cpp )
+set( kclock_DESKTOP	KClock.desktop )
+
+set( LIBART_SCREENSAVERS kclock )
+
+##### LIBART conditions #########################
+
+if( WITH_LIBART )
+  list( APPEND SCREENSAVERS ${LIBART_SCREENSAVERS} )
+
+  include_directories( ${LIBART_INCLUDE_DIRS} )
+  link_directories( ${LIBART_LIBRARY_DIRS} )
+  foreach( saver ${LIBART_SCREENSAVERS} )
+    list ( APPEND ${saver}_LINK ${LIBART_LIBRARIES} )
+  endforeach( saver ${LIBART_SCREENSAVERS} )
+endif( WITH_LIBART )
+
+##### GL conditions #############################
+
+if( WITH_OPENGL )
+  if( WITH_ARTS )
+    list( APPEND OPENGL_SCREENSAVERS ${GL_ARTS_SCREENSAVERS} )
+  endif( WITH_ARTS )
+
+  list( APPEND SCREENSAVERS ${OPENGL_SCREENSAVERS} )
+  
+  include_directories( ${OPENGL_INCLUDE_DIRS} )
+  link_directories( ${OPENGL_LIBRARY_DIRS} )
+  foreach( saver ${OPENGL_SCREENSAVERS} )
+    list ( APPEND ${saver}_LINK ${OPENGL_LIBRARIES} )
+  endforeach( saver ${OPENGL_SCREENSAVERS} )
+    
+endif( WITH_OPENGL )
+
+##### add normal screensavers ###################
+
+# FIXME: check for X includes/libraries
+#        this screensavers will work only in X
+list( APPEND SCREENSAVERS ${X11_SCREENSAVERS} )
+list( APPEND SCREENSAVERS ${NORMAL_SCREENSAVERS} )
+	
+##### create install/compile rules ##############
+foreach( saver ${SCREENSAVERS} )
+  tde_add_executable( ${saver}.kss AUTOMOC
+    SOURCES ${${saver}_SOURCES}
+    LINK kscreensaver-shared kdeui-shared ${${saver}_LINK}
+    DESTINATION ${BIN_INSTALL_DIR}
+  )
+  install( FILES ${${saver}_DESKTOP} 
+    DESTINATION ${APPS_INSTALL_DIR}/System/ScreenSavers )
+endforeach( saver ${SCREENSAVERS} )
+
+##### install various data ######################
+
+install( FILES image.png kscience.png particle.png
+    DESTINATION ${DATA_INSTALL_DIR}/kscreensaver )
+
+# Actually the only screensaver tha uses this data is kfiresaver 
+add_subdirectory( data )
diff --git a/kscreensaver/kdesavers/data/CMakeLists.txt b/kscreensaver/kdesavers/data/CMakeLists.txt
new file mode 100644
index 00000000..c9718d9a
--- /dev/null
+++ b/kscreensaver/kdesavers/data/CMakeLists.txt
@@ -0,0 +1,17 @@
+#################################################
+#
+#  (C) 2011 Golubev Alexander
+#  fatzer2 (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( FILES
+    kfs_particle.png kfs_particle_flare.png
+	kfs_particle_diastar.png kfs_kde.png 
+	kfs_tux.png kfs_letters1.png kfs_letters2.png 
+	kfs_letters.desc kfs_explode.ogg kfs_debris.ogg 
+	DESTINATION ${DATA_INSTALL_DIR}/kfiresaver )
diff --git a/kscreensaver/kpartsaver/CMakeLists.txt b/kscreensaver/kpartsaver/CMakeLists.txt
new file mode 100644
index 00000000..b546c5d1
--- /dev/null
+++ b/kscreensaver/kpartsaver/CMakeLists.txt
@@ -0,0 +1,33 @@
+#################################################
+#
+#  (C) 2011 Golubev Alexander
+#  fatzer2 (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+##### desktop files #############################
+
+install( FILES kpartsaver.desktop 
+    DESTINATION ${APPS_INSTALL_DIR}/System/ScreenSavers )
+
+##### kpart_cde ##################################
+
+tde_add_executable( kpartsaver.kss AUTOMOC
+  SOURCES kpartsaver.cpp configwidget.ui
+  LINK kscreensaver-shared kio-shared
+  DESTINATION ${BIN_INSTALL_DIR}
+)
diff --git a/kscreensaver/kxsconfig/CMakeLists.txt b/kscreensaver/kxsconfig/CMakeLists.txt
new file mode 100644
index 00000000..99f44e54
--- /dev/null
+++ b/kscreensaver/kxsconfig/CMakeLists.txt
@@ -0,0 +1,66 @@
+#################################################
+#
+#  (C) 2011 Golubev Alexander
+#  fatzer2 (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${X11_INCLUDE_DIR}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${X11_LIBRARY_DIR}
+)
+
+##### kxsconfig #################################
+set( target kxsconfig )
+
+set( ${target}_SRCS
+   kxscontrol.cpp kxsitem.cpp kxsxml.cpp kxsconfig.cpp )
+
+tde_add_executable( ${target} AUTOMOC
+  SOURCES ${${target}_SRCS}
+  LINK kio-shared ${X11_Xt_LIB}
+  DESTINATION ${BIN_INSTALL_DIR}
+)
+
+##### kxsrun ####################################
+set( target kxsrun )
+
+set( ${target}_SRCS
+   kxsrun.cpp kxscontrol.cpp kxsitem.cpp kxsxml.cpp )
+
+tde_add_executable( ${target} AUTOMOC
+  SOURCES ${${target}_SRCS}
+  LINK kio-shared
+  DESTINATION ${BIN_INSTALL_DIR}
+)
+
+##### install desktops ##########################
+# code from kde4
+FILE(GLOB _desktopfiles "ScreenSavers/*.desktop" )
+foreach(_currentdesktopfile ${_desktopfiles})
+  STRING(REGEX REPLACE ".desktop" "" _newitem "${_currentdesktopfile}" )
+  #MESSAGE(STATUS "newItem <${_newitem}>")
+  GET_FILENAME_COMPONENT(_screensaverName ${_newitem} NAME_WE)
+  #MESSAGE(STATUS "name without extension
+  find_file(XSCREENSAVER_FILE_FOUND ${_screensaverName}.xml PATHS ${XSCREENSAVER_CONFIG_DIR} )
+  if(XSCREENSAVER_FILE_FOUND)
+    MESSAGE(STATUS "xscreensaver name ${_screensaverName} found")
+    install(FILES ${_currentdesktopfile} DESTINATION  ${APPS_INSTALL_DIR}/System/ScreenSavers )
+  else(XSCREENSAVER_FILE_FOUND)
+    MESSAGE(STATUS "xscreensaver name ${_screensaverName} not found")
+  endif(XSCREENSAVER_FILE_FOUND)
+  unset(XSCREENSAVER_FILE_FOUND CACHE)
+endforeach(_currentdesktopfile ${_desktopfiles})
+
diff --git a/kscreensaver/xsavers/CMakeLists.txt b/kscreensaver/xsavers/CMakeLists.txt
new file mode 100644
index 00000000..8cbd8fac
--- /dev/null
+++ b/kscreensaver/xsavers/CMakeLists.txt
@@ -0,0 +1,52 @@
+#################################################
+#
+#  (C) 2011 Golubev Alexander
+#  fatzer2 (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TDE_INCLUDE_DIR}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+##### shared source ##########################
+
+set( BASE_SRCS main.cpp demowin.cpp saver.cpp helpers.cpp )
+set( XL_SRCS xlock.cpp )
+
+##### kswarm #################################
+
+tde_add_executable( kswarm.kss AUTOMOC
+  SOURCES swarm.cpp ${BASE_SRCS} ${XL_SRCS}
+  LINK kdeui-shared
+  DESTINATION ${BIN_INSTALL_DIR}
+)
+
+install( FILES KSwarm.desktop DESTINATION ${APPS_INSTALL_DIR}/System/ScreenSavers )
+
+##### kswarm #################################
+
+if( WITH_OPENGL )
+  include_directories( ${OPENGL_INCLUDE_DIRS} )
+  link_directories( ${OPENGL_LIBRARY_DIRS} )
+  tde_add_executable( kspace.kss AUTOMOC
+    SOURCES space.cpp ${BASE_SRCS} ${XL_SRCS}
+	LINK kdeui-shared ${OPENGL_LIBRARIES}
+    DESTINATION ${BIN_INSTALL_DIR}
+  )
+  
+  install( FILES KSpace.desktop DESTINATION ${APPS_INSTALL_DIR}/System/ScreenSavers )
+endif( WITH_OPENGL )
+
+