conversion to the cmake building system

Signed-off-by: gregory guy <[email protected]>

9 files changed, 217 insertions, 2 deletions

diff --git a/CMakeLists.txt b/CMakeLists.txt
new file mode 100644
index 0000000..5ddb511
--- /dev/null
+++ b/CMakeLists.txt
@@ -0,0 +1,76 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8 )
+
+
+#### general package setup
+
+project( tdeio-apt )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### user requested modules
+
+option( BUILD_ALL "Build all" ON                             )
+option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H -UTQT_NO_COMPAT )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( src )
+tde_conditional_add_subdirectory( BUILD_TRANSLATIONS po ) 
+
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )
diff --git a/ConfigureChecks.cmake b/ConfigureChecks.cmake
new file mode 100644
index 0000000..7733a2a
--- /dev/null
+++ b/ConfigureChecks.cmake
@@ -0,0 +1,45 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  if( NOT UNIX )
+    tde_message_fatal( "gcc visibility support was requested, but your system is not *NIX" )
+  endif( NOT UNIX )
+  set( __KDE_HAVE_GCC_VISIBILITY 1 )
+  set( CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
+  set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
+endif( WITH_GCC_VISIBILITY )
+
+
+##### gettext
+
+if( BUILD_TRANSLATIONS )
+  include( FindGettext )
+  if( GETTEXT_FOUND )
+    set( MSGFMT_EXECUTABLE ${GETTEXT_MSGFMT_EXECUTABLE} 
+      CACHE FILEPATH "path to msgfmt executable" )
+  endif( GETTEXT_FOUND )
+  
+  if( NOT MSGFMT_EXECUTABLE )
+    tde_message_fatal( "msgfmt is required but was not found on your system." )
+  endif( NOT MSGFMT_EXECUTABLE )
+endif( BUILD_TRANSLATIONS )
+
diff --git a/config.h.cmake b/config.h.cmake
new file mode 100644
index 0000000..61ede3a
--- /dev/null
+++ b/config.h.cmake
@@ -0,0 +1,8 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@
diff --git a/po/CMakeLists.txt b/po/CMakeLists.txt
new file mode 100644
index 0000000..f943cac
--- /dev/null
+++ b/po/CMakeLists.txt
@@ -0,0 +1,5 @@
+file( GLOB _srcs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.po )
+
+if( _srcs )
+  tde_create_translation( LANG auto OUTPUT_NAME ${PROJECT_NAME} )
+endif( )
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
new file mode 100644
index 0000000..4120377
--- /dev/null
+++ b/src/CMakeLists.txt
@@ -0,0 +1,53 @@
+add_subdirectory( parsers )
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}/parsers
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}/parsers
+)
+
+
+##### tdeio_apt (kpart)
+
+tde_add_kpart( tdeio_apt AUTOMOC
+
+  SOURCES
+        aptcache.cpp
+        apt.cpp
+        regexps.cpp
+        packagemanager.cpp
+        dpkg.cpp
+  LINK
+     tdecore-shared
+     tdeui-shared
+     parsers-static
+     
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)
+
+
+##### other data
+
+install(
+    FILES apt.protocol apt+http.protocol
+    DESTINATION ${SERVICES_INSTALL_DIR}
+)
+
+install(
+    FILES tdeio_apt.css tdedeb_logo.png
+    DESTINATION ${DATA_INSTALL_DIR}/tdeio_apt/
+)
+
+install(
+    FILES apt-search.desktop apt-file.desktop apt-files.desktop
+   DESTINATION ${SERVICES_INSTALL_DIR}/searchproviders
+)
diff --git a/src/Makefile.am b/src/Makefile.am
index c195f1f..c3ff703 100644
--- a/src/Makefile.am
+++ b/src/Makefile.am
@@ -13,7 +13,7 @@ protocoldir = $(kde_servicesdir)
 protocol_DATA = apt.protocol apt+http.protocol
 
 appdatadir = $(kde_datadir)/tdeio_apt/
-appdata_DATA = tdeio_apt.css kdedeb_logo.png
+appdata_DATA = tdeio_apt.css tdedeb_logo.png
 
 messages: rc.cpp
 	$(XGETTEXT) *.cpp -o $(podir)/tdeio_apt.pot
diff --git a/src/apt.cpp b/src/apt.cpp
index 8c8f362..fdc9751 100644
--- a/src/apt.cpp
+++ b/src/apt.cpp
@@ -229,7 +229,7 @@ AptProtocol::AptProtocol( const TQCString &pool_socket, const TQCString &app_soc
   m_stylesheet = dirs->findResource( "data", "tdeio_apt/tdeio_apt.css" );
 
   m_logo = dirs->findResource( "data", "tdeio_apt/" 
-          + TDEGlobal::config() -> readEntryUntranslated("logo", "kdedeb_logo.png" ) );
+          + TDEGlobal::config() -> readEntryUntranslated("logo", "tdedeb_logo.png" ) );
 
   m_header_background = dirs->findResource( "data", "tdeio_apt/" 
           + TDEGlobal::config() -> readEntryUntranslated("background", "headerbg.png" ) );
diff --git a/src/parsers/CMakeLists.txt b/src/parsers/CMakeLists.txt
new file mode 100644
index 0000000..116447b
--- /dev/null
+++ b/src/parsers/CMakeLists.txt
@@ -0,0 +1,28 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+
+##### parsers (static)
+
+tde_add_library( parsers STATIC_PIC AUTOMOC
+
+  SOURCES
+        list.cpp
+        search.cpp
+        policy.cpp
+        show.cpp
+        parsers.cpp
+        filesearch.cpp
+  LINK
+     tdeio-shared
+)
diff --git a/src/kdedeb_logo.png b/src/tdedeb_logo.png
index ce01333..ce01333 100644
--- a/src/kdedeb_logo.png
+++ b/src/tdedeb_logo.png