1 files changed, 84 insertions, 0 deletions
diff --git a/arts/modules/common/CMakeLists.txt b/arts/modules/common/CMakeLists.txt
new file mode 100644
index 00000000..329fb104
--- /dev/null
+++ b/arts/modules/common/CMakeLists.txt
@@ -0,0 +1,84 @@
+#################################################
+#
+#  (C) 2017 Slávek Banko
+#  slavek (DOT) banko (AT) axis.cz
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( mcopclass )
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/arts/modules
+  ${CMAKE_BINARY_DIR}/arts/gui/common
+  ${CMAKE_BINARY_DIR}/arts/midi
+  ${CMAKE_BINARY_DIR}/arts/modules
+  ${CMAKE_BINARY_DIR}/arts/modules/common
+  ${CMAKE_BINARY_DIR}/arts/modules/effects
+  ${CMAKE_BINARY_DIR}/arts/modules/mixers
+  ${CMAKE_BINARY_DIR}/arts/modules/synth
+  ${CMAKE_BINARY_DIR}/arts/runtime
+  ${CMAKE_BINARY_DIR}
+  ${ARTS_INCLUDE_DIRS}
+  ${TQT_INCLUDE_DIRS}
+  ${TDE_INCLUDE_DIR}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${ARTS_LIBRARY_DIRS}
+)
+
+
+##### artsmodulescommon (library) ###############
+
+tde_add_library( artsmodulescommon SHARED
+  SOURCES
+    artsmodulescommon.cc effectrackslot_impl.cc
+    env_container_impl.cc env_context_impl.cc
+    env_effectrackitem_impl.cc env_instrumentitem_impl.cc
+    env_item_impl.cc env_mixeritem_impl.cc
+  VERSION 0.0.0
+  LINK
+    artsgui_idl-shared artsmidi_idl-shared artsmodulessynth-shared
+    tdecore-shared mcop artsflow artsflow_idl gthread-2.0 ${ARTS_LIBRARIES}
+  DESTINATION ${LIB_INSTALL_DIR}
+)
+
+add_custom_command(
+  OUTPUT
+    artsmodulescommon.cc artsmodulescommon.h
+    artsmodulescommon.mcopclass artsmodulescommon.mcoptype
+  COMMAND ${ARTS_MCOPIDL_EXECUTABLE} -t
+    -I${CMAKE_SOURCE_DIR}/arts/gui/common
+    -I${CMAKE_SOURCE_DIR}/arts/midi
+    -I${CMAKE_SOURCE_DIR}/arts/modules
+    -I${CMAKE_SOURCE_DIR}/arts/modules/common
+    -I${CMAKE_SOURCE_DIR}/arts/modules/effects
+    -I${CMAKE_SOURCE_DIR}/arts/modules/mixers
+    -I${CMAKE_SOURCE_DIR}/arts/modules/synth
+    -I${ARTS_INCLUDEDIR}
+    ${CMAKE_CURRENT_SOURCE_DIR}/artsmodulescommon.idl
+  DEPENDS artsmodulescommon.idl
+)
+
+
+##### other data ################################
+
+install(
+  FILES
+    artsmodulescommon.idl
+    ${CMAKE_CURRENT_BINARY_DIR}/artsmodulescommon.h
+  DESTINATION ${INCLUDE_INSTALL_DIR}/arts
+)
+
+install(
+  FILES
+    ${CMAKE_CURRENT_BINARY_DIR}/artsmodulescommon.mcoptype
+    ${CMAKE_CURRENT_BINARY_DIR}/artsmodulescommon.mcopclass
+  DESTINATION ${LIB_INSTALL_DIR}/mcop
+)