Move PerlQt

3 files changed, 260 insertions, 0 deletions

diff --git a/PerlTQt/tutorials/t11/CannonField.pm b/PerlTQt/tutorials/t11/CannonField.pm
new file mode 100644
index 0000000..0806f66
--- /dev/null
+++ b/PerlTQt/tutorials/t11/CannonField.pm
@@ -0,0 +1,146 @@
+package CannonField;
+use strict;
+use TQt;
+use TQt::isa qw(TQt::Widget);
+use TQt::signals
+	angleChanged => ['int'],
+	forceChanged => ['int'];
+use TQt::slots
+	setAngle => ['int'],
+	setForce => ['int'],
+	shoot => [],
+	moveShot => [];
+use TQt::attributes qw(
+	ang
+	f
+
+	timerCount
+	autoShootTimer
+	shoot_ang
+	shoot_f
+);
+use POSIX qw(atan);
+
+sub angle () { ang }
+sub force () { f }
+
+sub NEW {
+    shift->SUPER::NEW(@_);
+
+    ang = 45;
+    f = 0;
+    timerCount = 0;
+    autoShootTimer = TQt::Timer(this, "movement handler");
+    this->connect(autoShootTimer, TQT_SIGNAL('timeout()'), TQT_SLOT('moveShot()'));
+    shoot_ang = 0;
+    shoot_f = 0;
+    setPalette(TQt::Palette(TQt::Color(250, 250, 200)));
+}
+
+sub setAngle {
+    my $degrees = shift;
+    $degrees = 5 if $degrees < 5;
+    $degrees = 70 if $degrees > 70;
+    return if ang == $degrees;
+    ang = $degrees;
+    repaint(cannonRect(), 0);
+    emit angleChanged(ang);
+}
+
+sub setForce {
+    my $newton = shift;
+    $newton = 0 if $newton < 0;
+    return if f == $newton;
+    f = $newton;
+    emit forceChanged(f);
+}
+
+sub shoot {
+    return if autoShootTimer->isActive;
+    timerCount = 0;
+    shoot_ang = ang;
+    shoot_f = f;
+    autoShootTimer->start(50);
+}
+
+sub moveShot {
+    my $r = TQt::Region(shotRect());
+    timerCount++;
+
+    my $shotR = shotRect();
+
+    if($shotR->x > width() || $shotR->y > height()) {
+	autoShootTimer->stop;
+    } else {
+	$r = $r->unite(TQt::Region($shotR));
+    }
+    repaint($r);
+}
+
+sub paintEvent {
+    my $e = shift;
+    my $updateR = $e->rect;
+    my $p = TQt::Painter(this);
+
+    paintCannon($p)  if $updateR->intersects(cannonRect());
+    paintShot($p)    if autoShootTimer->isActive and $updateR->intersects(shotRect());
+}
+
+sub paintShot {
+    my $p = shift;
+    $p->setBrush(&black);
+    $p->setPen(&NoPen);
+    $p->drawRect(shotRect());
+}
+
+my $barrelRect = TQt::Rect(33, -4, 15, 8);
+
+sub paintCannon {
+    my $p = shift;
+    my $cr = cannonRect();
+    my $pix = TQt::Pixmap($cr->size);
+    $pix->fill(this, $cr->topLeft);
+
+    my $tmp = TQt::Painter($pix);
+    $tmp->setBrush(&blue);
+    $tmp->setPen(&NoPen);
+
+    $tmp->translate(0, $pix->height - 1);
+    $tmp->drawPie(TQt::Rect(-35, -35, 70, 70), 0, 90*16);
+    $tmp->rotate(- ang);
+    $tmp->drawRect($barrelRect);
+    $tmp->end;
+
+    $p->drawPixmap($cr->topLeft, $pix);
+}
+
+sub cannonRect {
+    my $r = TQt::Rect(0, 0, 50, 50);
+    $r->moveBottomLeft(rect()->bottomLeft);
+    return $r;
+}
+
+sub shotRect {
+    my $gravity = 4;
+
+    my $time     = timerCount / 4.0;
+    my $velocity = shoot_f;
+    my $radians  = shoot_ang*3.14159265/180;
+
+    my $velx     = $velocity*cos($radians);
+    my $vely     = $velocity*sin($radians);
+    my $x0       = ($barrelRect->right + 5)*cos($radians);
+    my $y0       = ($barrelRect->right + 5)*sin($radians);
+    my $x        = $x0 + $velx*$time;
+    my $y        = $y0 + $vely*$time - 0.5*$gravity*$time**2;
+
+    my $r = TQt::Rect(0, 0, 6, 6);
+    $r->moveCenter(TQt::Point(int($x), height() - 1 - int($y)));
+    return $r;
+}
+
+sub sizePolicy {
+    TQt::SizePolicy(&TQt::SizePolicy::Expanding, &TQt::SizePolicy::Expanding);
+}
+
+1;
diff --git a/PerlTQt/tutorials/t11/LCDRange.pm b/PerlTQt/tutorials/t11/LCDRange.pm
new file mode 100644
index 0000000..ab63af0
--- /dev/null
+++ b/PerlTQt/tutorials/t11/LCDRange.pm
@@ -0,0 +1,43 @@
+package LCDRange;
+use strict;
+use TQt;
+use TQt::isa qw(TQt::VBox);
+use TQt::slots 
+	setValue => ['int'],
+	setRange => ['int', 'int'];
+use TQt::signals
+	valueChanged => ['int'];
+use TQt::attributes qw(
+	slider
+);
+
+sub NEW {
+    shift->SUPER::NEW(@_);
+
+    my $lcd = TQt::LCDNumber(2, this, "lcd");
+
+    slider = TQt::Slider(&Horizontal, this, "slider");
+    slider->setRange(0, 99);
+    slider->setValue(0);
+    $lcd->connect(slider, TQT_SIGNAL('valueChanged(int)'), TQT_SLOT('display(int)'));
+    this->connect(slider, TQT_SIGNAL('valueChanged(int)'), TQT_SIGNAL('valueChanged(int)'));
+
+    setFocusProxy(slider);
+}
+
+sub value { slider->value }
+
+sub setValue { slider->setValue(shift) }
+
+sub setRange {
+    my($minVal, $maxVal) = @_;
+    if($minVal < 0 || $maxVal > 99 || $minVal > $maxVal) {
+	warn "LCDRange::setRange($minVal,$maxVal)\n" .
+	     "\tRange must be 0..99\n" .
+	     "\tand minVal must not be greater than maxVal\n";
+	return;
+    }
+    slider->setRange($minVal, $maxVal);
+}
+
+1;
diff --git a/PerlTQt/tutorials/t11/t11.pl b/PerlTQt/tutorials/t11/t11.pl
new file mode 100644
index 0000000..d493b1e
--- /dev/null
+++ b/PerlTQt/tutorials/t11/t11.pl
@@ -0,0 +1,71 @@
+#!/usr/bin/perl -w
+use strict;
+use blib;
+
+package MyWidget;
+use strict;
+use TQt;
+use TQt::isa qw(TQt::Widget);
+
+use LCDRange;
+use CannonField;
+
+sub NEW {
+    shift->SUPER::NEW(@_);
+
+    my $quit = TQt::PushButton("&Quit", this, "quit");
+    $quit->setFont(TQt::Font("Times", 18, &TQt::Font::Bold));
+
+    TQt::app->connect($quit, TQT_SIGNAL('clicked()'), TQT_SLOT('quit()'));
+
+    my $angle = LCDRange(this, "angle");
+    $angle->setRange(5, 70);
+
+    my $force = LCDRange(this, "force");
+    $force->setRange(10, 50);
+
+    my $cannonField = CannonField(this, "cannonField");
+
+    $cannonField->connect($angle, TQT_SIGNAL('valueChanged(int)'), TQT_SLOT('setAngle(int)'));
+    $angle->connect($cannonField, TQT_SIGNAL('angleChanged(int)'), TQT_SLOT('setValue(int)'));
+
+    $cannonField->connect($force, TQT_SIGNAL('valueChanged(int)'), TQT_SLOT('setForce(int)'));
+    $force->connect($cannonField, TQT_SIGNAL('forceChanged(int)'), TQT_SLOT('setValue(int)'));
+
+    my $shoot = TQt::PushButton('&Shoot', this, "shoot");
+    $shoot->setFont(TQt::Font("Times", 18, &TQt::Font::Bold));
+
+    $cannonField->connect($shoot, TQT_SIGNAL('clicked()'), TQT_SLOT('shoot()'));
+
+    my $grid = TQt::GridLayout(this, 2, 2, 10);
+    $grid->addWidget($quit, 0, 0);
+    $grid->addWidget($cannonField, 1, 1);
+    $grid->setColStretch(1, 10);
+
+    my $leftBox = TQt::VBoxLayout;
+    $grid->addLayout($leftBox, 1, 0);
+    $leftBox->addWidget($angle);
+    $leftBox->addWidget($force);
+
+    my $topBox = TQt::HBoxLayout;
+    $grid->addLayout($topBox, 0, 1);
+    $topBox->addWidget($shoot);
+    $topBox->addStretch(1);
+
+    $angle->setValue(60);
+    $force->setValue(25);
+    $angle->setFocus();
+}
+
+package main;
+use TQt;
+use MyWidget;
+
+TQt::Application::setColorSpec(&TQt::Application::CustomColor);
+my $a = TQt::Application(\@ARGV);
+
+my $w = MyWidget;
+$w->setGeometry(100, 100, 500, 355);
+$a->setMainWidget($w);
+$w->show;
+exit $a->exec;