14.0.8 ebuilds for everything in trinity-apps that I could make build back in June.

Signed-off-by: E. Liddell <[email protected]>

2 files changed, 94 insertions, 0 deletions

diff --git a/trinity-apps/amarok/Manifest b/trinity-apps/amarok/Manifest
new file mode 100644
index 00000000..8b197775
--- /dev/null
+++ b/trinity-apps/amarok/Manifest
@@ -0,0 +1,2 @@
+DIST amarok-trinity-14.0.7.tar.xz 10043532 BLAKE2B e2ba4fa84c3449c394ddb0dabbdf1b7167e5645128d8c2d09ead2061be980b97887c6177e59f9978d5cf5e21f283c34b7ac9f15b6e5e346f4d976cdd9e809add SHA512 1794603c6b8cbe2a1105d28d8c30bf6cc6c850c54ae154fb90f0ea0743d283490770d91b4df82ad46b4056c7cece8795b28bd14bef98b934a439897b71609ba6
+DIST amarok-trinity-14.0.8.tar.xz 10039812 BLAKE2B 968464a452b22946c37a8f6aecf34013e4e0703cc0f2816086dbb97d131c6c6262cf0844b4af151a2987badb7676c0509fb606d0a7e5ed6c34b087b8b5f7104d SHA512 8db0ac897ca4a52a3e161375cea7bf37d7874cea89de554282cf83687dae3f10df1d8ecade3bf59a0b79aad830e9807b4a4d626a70b16f59f063541e253016a4
diff --git a/trinity-apps/amarok/amarok-14.0.8.ebuild b/trinity-apps/amarok/amarok-14.0.8.ebuild
new file mode 100644
index 00000000..561f3b10
--- /dev/null
+++ b/trinity-apps/amarok/amarok-14.0.8.ebuild
@@ -0,0 +1,92 @@
+# Copyright 2020 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+TRINITY_MODULE_TYPE="applications"
+
+TRINITY_EXTRAGEAR_PACKAGING="yes"
+TRINITY_HANDBOOK="optional"
+
+TRINITY_LANGS="af ar az be bg bn br ca cs cy da de el en_GB eo es
+	et eu fa fi fr ga gl he hi hu id is it ja ka km ko ku lo lt mk
+	ms nb nds ne nl nn pa pl pt pt_BR ro ru rw se sk sl sq sr sr@Latn
+	ss sv ta tg th tr uk uz uz@cyrillic zh_CN zh_TW"
+
+TRINITY_DOC_LANGS="da de es et fr it nl pl pt pt_BR ru sv"
+
+inherit trinity-base-2
+
+DESCRIPTION="Advanced music player for TDE."
+KEYWORDS="~amd64 ~x86"
+HOMEPAGE="http://trinitydesktop.org/"
+LICENSE="|| ( GPL-2 GPL-3 )"
+
+need-trinity
+
+SLOT="${TRINITY_VER}"
+
+# Notes about the ebuild:
+#
+# - This version supports three engines: Xine, Yauap, and Akode.
+#   The only ones supported at the moment are Xine and Akode.
+#   Yauap isn't in Portage tree, but could be added later.
+#
+# - Rio Karma support needs libkarma which neeeds to be added to our overlay later.
+#
+# - No Support for DAAP because it's not tested if that works with Mongrel2.
+#
+# - As of January 2020, building with anything newer than xine-lib-1.2.9 will fail.
+#
+# - Otherwise the ebuild should offer all what can be done with CMake at the moment.
+
+IUSE+=" konqsidebar +xine ipod riokarma ifp njb mtp mp4
+	inotify visualization amazon mysql postgres opengl akode"
+
+REQUIRED_USE="|| ( xine akode )"
+
+DEPEND+="
+	dev-lang/ruby:*
+	media-libs/taglib
+	dev-db/sqlite
+	xine? ( <media-libs/xine-lib-1.2.10 )
+	akode? ( =media-libs/akode-${PV} )
+	mp4? ( media-libs/libmp4v2 )
+	ipod? ( media-libs/libgpod )
+	riokarma? ( media-libs/libkarma )
+	ifp? ( media-libs/libifp )
+	njb? ( media-libs/libnjb )
+	opengl? ( virtual/opengl )
+	postgres? ( dev-db/postgresql )
+	mtp? ( media-libs/libmtp )
+	mysql? ( virtual/mysql )
+	visualization? (
+		media-libs/libsdl
+		media-plugins/libvisual-plugins
+	)
+"
+RDEPEND+=" ${DEPEND}"
+
+src_configure() {
+	mycmakeargs=(
+		-DWITH_AMAZON="$(usex amazon)"
+		-DWITH_KONQSIDEBAR="$(usex konqsidebar)"
+		-DWITH_XINE="$(usex xine)"
+		-DWITH_AKODE="$(usex akode)"
+		-DWITH_IPOD="$(usex ipod)"
+		-DWITH_RIOKARMA="$(usex riokarma)"
+		-DWITH_IFP="$(usex ifp)"
+		-DWITH_NJB="$(usex njb)"
+		-DWITH_MTP="$(usex mtp)"
+		-DWITH_MP4V2="$(usex mp4)"
+		-DWITH_INOTIFY="$(usex inotify)"
+		-DWITH_OPENGL="$(usex opengl)"
+		-DWITH_LIBVISUAL="$(usex visualization)"
+		-DWITH_MYSQL="$(usex mysql)"
+		-DWITH_POSTGRESQL="$(usex postgres)"
+		-DWITH_SYSTEM_SQLITE=ON
+		-DWITH_YAUAP=OFF
+		-DWITH_DAAP=OFF
+	)
+
+	trinity-base-2_src_configure
+}